The Anchorage

Personal website of Gregory K. Maxey, Commander USN (Retired)

• Quarterdeck
• What's New
• Microsoft Word Tips
• Consulting
• Chain Locker
• Lucky Bag
• Contact
• Search

Do you have ad-blocking software enabled? While I respect your right to do so, your donations and the minimal advertisements on this site help to defray internet and other costs of providing this content. Please consider excluding this website from blocking or turning off the blocker while browsing this site.

This Microsoft Word Tips & Microsoft Word Help page provides some helpful links to page numbering reference material plus some tips of my own.

 The Word MVP FAQ site has several helpful articles on page numbering:  Numbering FAQs

Dual Page Numbering

Sometimes people ask: How to display both "Page X of Y Pages" and "Page X of Z Pages" in the header/footer of a document?

• Where X is the page number referenced to Y or Z.
• Y is the total number of pages in the document.
• Z is the total number of pages in an individual "content" section.

Note:  I use the term "content section" to differentiate and define a document section formed with section breaks consisting of like content (e.g., Marketing, Sales, etc.) from sections formed with section breaks for the purpose of document layout (e.g., page orientation, etc.)

For this demonstration I have used an eight page document containing three sections. Section 1 contains two pages, section 2 contains three pages and section 3 contains three pages. The illustration below depicts dual numbering in section 1:

• Applying a dual numbering format in section 1 is simple. As shown in the illustration below, the numbering depicted above results from two field pairs. {Page} and {Numpages} fields are used for the X of Y format on the left and {Page} and {SectionPages} fields are used for the X of Z format on the right.

• A problem arises in section 2 and subsequent sections using that simple process.  As you may know, a { PAGE } field can be formatted to "Continue from ..." or "Start at ..." in each new section of a document, but not both!!
• Choose "Continue from previous section" in order that the left side page numbering continues throughout the document.  This is also important for proper page number display in a table of contents.
• However, this presents the problem depicted below:

• To resolve this issue, you can retrieve the page number of the last page of the previous section and subtract that value from the {Page} field value returned in right hand side construction of the current section header.
• Add a bookmark to the last word or character in "content" section of your document.  Here I havae added a bookmark "S1" to the last word in section 1. The bookmarks you add serve as the reference mark for PageRef fields explained below.

• Each "content" section will require a unique field construction so the next step is to break the links between the "content" sections.

• Now modify the right hand side field construction in the "content" section 2 and 3 headers:

The page value in the right hand construction is reset to 1 by subtracting the page number of the previous page form the page number of the current page.


Here the page number of the last page in section 2 pages is subtracted.


Dual numbering in "content" section 2.


Dual numbering in "content" section 3.


Resulting numbering in table of contents.

You can use the following VBA procedure to quickly add the necessary bookmarks and nested fields codes needed for section numbering in a document.  The code allows you to add the section page numbering centered in either the headers or footers of your document.  From there you can easily cut and paste them to better suit your requirements.

Sub InsertSectionPageNumbering()
'Developed by Greg Maxey and Doug Robbins.
Dim lngIndex As Long, lngHF As Long
Dim oRng As Range
Dim oFld As Field, oFldQ As Field
Dim strPlacement As String
Dim bUserSetting As Boolean
  Select Case UCase(InputBox("Enter ""F"" to place section numbering in footers." _
         & "Enter ""H"" to place section numbering in headers.", "Placement", "F"))
    Case "H"
      strPlacement = "Headers"
    Case "F"
      strPlacement = "Footers"
    Case Else
      Exit Sub
  End Select
  With ActiveDocument
    For lngIndex = 1 To .Sections.Count
      .Bookmarks.Add "S" & lngIndex, .Sections(lngIndex).Range.Characters.Last
    Next lngIndex
    bUserSetting = ActiveWindow.View.ShowFieldCodes
    ActiveWindow.View.ShowFieldCodes = True
    FirstSectionSetup .Sections(1), strPlacement
    For lngIndex = 2 To .Sections.Count
      AllOtherSectionSetup .Sections(lngIndex), lngIndex, strPlacement
    Next lngIndex
   .Fields.Update
    ActiveWindow.View.ShowFieldCodes = bUserSetting
  End With
End Sub

Sub FirstSectionSetup(ByRef oSect As Section, Optional strPlacement As String = "Footers")
Dim lngIndex As Long, lngHF As Long
Dim oRng As Range
Dim oFld As Field, oFldQ As Field
Dim oHDs As HeadersFooters

  With oSect
    If strPlacement = "Footers" Then
      Set oHDs = .Footers
    Else
      Set oHDs = .Headers
    End If
    For lngHF = 1 To oHDs.Count
      With oHDs(lngHF)
        Set oRng = .Range
        For Each oFld In oRng.Fields
          If InStr(oFld.Code, " QUOTE") > 0 Then
            oFld.Delete
            Exit For
          End If
        Next
        Set oFldQ = ActiveDocument.Fields.Add(oRng, wdFieldQuote, _
                    PreserveFormatting:=False)
        Set oRng = oFldQ.Code '.Characters.Last.Previous '.Previous '.Previous
        oRng.Collapse wdCollapseEnd
        oRng.Text = """Page "
        oRng.Collapse wdCollapseEnd
        ActiveDocument.Fields.Add oRng, wdFieldPage, PreserveFormatting:=False
        Set oRng = oFldQ.Code.Characters.Last '.Previous
        oRng.Collapse wdCollapseEnd
        oRng.Text = " of "
        Set oRng = oFldQ.Code.Characters.Last
        oRng.Collapse wdCollapseEnd
        ActiveDocument.Fields.Add oRng, wdFieldSectionPages, PreserveFormatting:=False
        Set oRng = oFldQ.Code.Characters.Last
        oRng.Collapse wdCollapseEnd
        oRng.Text = " Section Pages"""
        .Range.Paragraphs(1).Alignment = wdAlignParagraphCenter
      End With
    Next lngHF
  End With
End Sub

Sub AllOtherSectionSetup(ByRef oSect As Section, ByRef lngIndex As Long, _
                         Optional strPlacement As String = "Footers")
Dim lngHF As Long
Dim oRng As Range
Dim oFld As Field, oFldQ As Field
Dim oHDs As HeadersFooters
  With oSect
    If strPlacement = "Footers" Then
      Set oHDs = .Footers
    Else
      Set oHDs = .Headers
    End If
    For lngHF = 1 To oHDs.Count '.Footers.Count
      With oHDs(lngHF) '.Footers(lngHF)
        Set oRng = .Range
        .LinkToPrevious = False
        For Each oFld In oRng.Fields
          If InStr(oFld.Code, " QUOTE") > 0 Then
            oFld.Delete
            Exit For
          End If
        Next
        Set oRng = .Range
        oRng.Collapse wdCollapseStart
        Set oFldQ = ActiveDocument.Fields.Add(oRng, wdFieldQuote, _
                    PreserveFormatting:=False)
        Set oRng = oFldQ.Code
        oRng.Collapse wdCollapseEnd
        oRng.Text = """Page "
        oRng.Collapse wdCollapseEnd
        Set oFld = ActiveDocument.Fields.Add(oRng, wdFieldEmpty, "= ", _
                   PreserveFormatting:=False)
        Set oRng = oFld.Code.Characters.Last.Previous
        ActiveDocument.Fields.Add oRng, wdFieldPage, PreserveFormatting:=False
        Set oRng = oFld.Code.Characters.Last
        oRng.Collapse wdCollapseEnd
        oRng.Text = "- "
        Set oRng = oFld.Code.Characters.Last
        ActiveDocument.Fields.Add oRng, wdFieldEmpty, _
                 Text:="PAGEREF S" & lngIndex - 1, PreserveFormatting:=False
        Set oRng = oFldQ.Code.Characters.Last '.Previous
        oRng.Collapse wdCollapseEnd
        oRng.Text = " of "
        Set oRng = oFldQ.Code.Characters.Last
        oRng.Collapse wdCollapseEnd
        ActiveDocument.Fields.Add oRng, wdFieldSectionPages, PreserveFormatting:=False
        Set oRng = oFldQ.Code.Characters.Last
        oRng.Collapse wdCollapseEnd
        oRng.Text = " Section Pages"""
        .Range.Paragraphs(1).Alignment = wdAlignParagraphCenter
      End With
    Next lngHF
  End With
End Sub

Dual Page Numbering (with a twist)

What if the document contains one or more single "content" sections that requires two or more sections to facilitate page layout or formatting?  There's a twist!

In this situation, using the method described earlier, your page numbering is this section is all "twisted" up!

The first page is correct.


But page 2 and subsequent pages will are not!!

Again, to resolve this issue you can deduce the and display the correct number of "content" section pages using bookmarks, PageRef fields a forumla field.

Deducing "content" section pages.

Note:  Special thanks to friend and Word MVP Doug Robbins for his feedback, and suggestions for improving the dual numbering methods outlined above.

Conditional Numbering

I have a cover page on my document that I don't want numbered (or "How do I start numbering with Page 1 on the second or other subsequent page of my document?)

• There are several ways to solve this issue. The more traditional is using Page Setup and Layout to specify a Header and Footer "different first page" or sectioning your document using section breaks. Word MVP Suzanne Barnhill describes these method in detail here: How to setup a document with front matter numbered separately (toolbar) or How to setup a document with front matter numbered separately (ribbon).
• An alternative quick and easy solution is to simply use a condition IF field construction in the header:

Field construction


Document page 1 (front or cover page)


Document page 2 (first content page)

• The IF compares the page number with the value "1." If the page number is greater than 1, then the display is the actual page number - 1. If the page number is 1 then nothing is displayed. For more on conditional field usage and construction, see my Conditional Headers and Footers tip page.

Note: Using the conditional IF method works for simple page numbering. It will introduce errors if you attempt to use a Table of Contents in your document.

Number Every Other Page Consecutively

If you want to print on the front and back of your paper but only number the front side with a consecutive number, use a "different odd and even" header/footer layout and put the following field construction in the odd page headers:

Numbering each page as Odd or Even

If you want to to number each page in odd or even increments you can use:

That's it! I hope you have found this tips page useful and informative.

This page was last updated on March 09, 2021

Website Privacy Statement

Back to top    Back to Word Tips