The Anchorage

Personal website of Gregory K. Maxey, Commander USN (Retired)

• Quarterdeck
• What's New
• Microsoft Word Tips
• Consulting
• Chain Locker
• Lucky Bag
• Contact
• Search

Do you have ad-blocking software enabled? While I respect your right to do so, your donations and the minimal advertisements on this site help to defray internet and other costs of providing this content. Please consider excluding this website from blocking or turning off the blocker while browsing this site.

This Microsoft Word Help & Microsoft Word Tips page will show you how to use VBA to insert text "at" or "in" a bookmark and illustrate the advantages of inserting "in" a bookmark.

Background/Discussion

Bookmarks, as you may know, identifies a location in a document.  What you may not know, is that a bookmark defines a document range.

• You can go to (Ctrl+g) that range.
• You can put thing before that range.
• You can put things after after that range.
• You can put things "in" that range.

For this tips page I am going to create two empty bookmarks named bmAtBookmark and bmInBookmark.

Inserting text at a bookmark with VBA is very simple. A single line of code is all you need (See InsertAtBookmarkI and InsertAtBookmarkII in the code pane below:

Sub InsertAtBookmarkI()
  ActiveDocument.Bookmarks("bmAtBookmark").Range.InsertAfter "Some text here"
lbl_Exit:
  Exit Sub
End Sub

Sub InsertAtBookmarkII()
  ActiveDocument.Bookmarks("bmAtBookmark").Range.InsertAfter " Some more text here"
lbl_Exit:
  Exit Sub
End Sub

When you execute InsertAtBookmarkI, everything appears fine.

The complication arises when you want to insert additional or modified text at the bookmark. Execute InsertAtBookmarkII above and review the result:

Inserting text "in" a bookmark takes just a few extra lines of code but the results are well worth the effort. See: InsertInBookmarkI and InsertInBookmarkII in the code pane below:

Sub InsertInBookmarkI()
Dim oRng As Word.Range
  Set oRng = ActiveDocument.Bookmarks("bmInBookmark").Range
  oRng.Text = ActiveDocument.Bookmarks("bmInBookmark").Range.Text & "Some text here."
  ActiveDocument.Bookmarks.Add "bmInBookmark", oRng
lbl_Exit:
  Exit Sub
End Sub

Sub InsertInBookmarkII()
Dim oRng As Word.Range
  Set oRng = ActiveDocument.Bookmarks("bmInBookmark").Range
  oRng.Text = ActiveDocument.Bookmarks("bmInBookmark").Range.Text & "Some more text here."
  ActiveDocument.Bookmarks.Add "bmInBookmark", oRng
lbl_Exit:
  Exit Sub
End Sub

When you execute InsertInBookmarkI, the inserted content is bound by the bookmark range.

If you want to add additional text, execute InsertInBookmarkII.

Note: Modifying or defining a bookmark range with a VBA procedure destroys the bookmark! This is why putting text "in" a bookmark requires these extra steps:

• Define a range object and set it equal the existing bookmark range
• Use the range .Text property define the bookmark text (this destroys the original bookmark)
• Recreate the bookmark with the same name using the range object to define the location of the recreated bookmark

You should now see that by putting text "in" vice "at" a bookmark, you allow the document user to do something and then change his or her mind and do something different without messing up the document.

Delete the text following the bookmark bmAtBookmark and run the procedure InsertAtBookmarkIII provided below.

Sub InsertAtBookmarkIII()
ActiveDocument.Bookmarks("bmAtBookmark").Range.InsertAfter InputBox("What is your favorite color?")
lbl_Exit:
  Exit Sub
End Sub

As before, the result in the document looks fine. Now you've change your mind so run the code again the result is not so good.

First time looks fine.


Indecision, indecision ... leads to poor results.

Now try the following code and see if you aren't pleased with the result:

Sub InsertInBookmarkIII()
Dim oRng As Word.Range
  Set oRng = ActiveDocument.Bookmarks("bmInBookmark").Range
  oRng.Text = InputBox("What is your favorite color?")
  ActiveDocument.Bookmarks.Add "bmInBookmark", oRng
lbl_Exit:
  Exit Sub
End Sub

If you will write to bookmark ranges frequently or if you have a project involving several bookmark ranges, you should consider using a call in your procedure to a separate procedure just for writing to the bookmark range.  This can eliminate using repetitive code in your procedures.

Sub DemoWriteToBookmarkRange()
Dim strInput As String
  strInput = InputBox("What is your favorite color?")
  WriteToBookmarkRange ActiveDocument, "bmInBookmark", strInput
  strInput = InputBox("What is your favorite food?")
  WriteToBookmarkRange ActiveDocument, "bmInBookmarkFood", strInput
  strInput = InputBox("What is your favorite soft drink?")
  WriteToBookmarkRange ActiveDocument, "bmInBookmarkDrink", strInput
lbl_Exit:
  Exit Sub
End Sub

Sub WriteToBookmarkRange(ByRef oDoc As Document, bmName As String, strContent As String)
Dim oRng As Word.Range
  If oDoc.Bookmarks.Exists(bmName) Then
    Set oRng = oDoc.Bookmarks(bmName).Range
    oRng.Text = strContent
    oDoc.Bookmarks.Add bmName, oRng
  Else
    MsgBox "An error occurred while processing your document." _
    & vbCr & "The bookmark " & Chr(34) + bmName + Chr(34) & " does not exist.", _
    vbInformation, "Missing Bookmark"
  End If
lbl_Exit:
  Exit Sub
End Sub

Inserting file content in a bookmark

Inserting a file content using the .InsertfFile method in a bookmark is a little tricky. This is because when you use a range object with the .InsertFile method (e.g.,  oRng.InsertFile "D:\FileToInsert.docx"), the range ends up collapsed at the start of the inserted text vice at the end as would be expected.

You can use the following method to resolve this issue:

Sub InsertFileInBookmark()
Dim oRng As Range, oRngNC As Range
  Set oRng = ActiveDocument.Bookmarks("bmInBookmark").Range
  Set oRngNC = oRng.Characters.Last
  oRng.InsertFile ("D:\FileToInsert.docm")
  oRngNC.Characters.Last.Previous.Delete
  oRngNC.End = oRngNC.End - 1
  ActiveDocument.Bookmarks.Add "bmTarget", oRngNC
lbl_Exit:
  Exit Sub
End Sub

See: Installing Macros for instructions on how to set up and use the macros provided in this Microsoft Word Help & Microsoft Word Tips page.

That's it! I hope you have found this tips page useful and informative.

This page was last updated on March 09, 2021

Website Privacy Statement

Back to top    Back to Word Tips