Pass Data To/From a Userform
(A Microsoft Word Help & Tip page by Gregory K. Maxey)

Sub PassData1()
Dim myFrm As UserForm1
Dim strCaption As String
  'Get a dynamic value to be passed to the userform from the user.
  Do
    'Define dynamic caption for userform frame control.
    strCaption = InputBox("Enter a custom Frame1 Caption: ", _
        "Custom Caption", "Enter your shoe size e.g., 10D")
    'Did the user cancel the inputbox?
    If StrPtr(strCaption) = 0 Then Exit Sub
  Loop Until strCaption <> ""
  'Create\load the userform in memory.
  Set myFrm = New UserForm1
  With myFrm
    'Employ a direct reference a form built-in property.
    .Frame1.Caption = strCaption
    'Display the form.
    .Show
    If .Tag <> "Canceled" Then
      'Employ a direct reference to a form built-in property.
      MsgBox "You entered size " & UCase(.TextBox1.Text) & ". This" _
           & " is a valid size.", , "Data Returned"
    End If
  End With
  Set myFrm = Nothing
End Sub

Private Sub cmdOK_Click()
  If fcnSizeValidator(Me.TextBox1.Text) Then
    Me.Hide
  Else
    With Me
      .Frame1.Caption = Me.TextBox1.Text & " is invalid." _
                      & " Please enter a valid size."
      With .TextBox1
        .SetFocus
        .SelStart = 0
        .SelLength = Len(.Text)
      End With
    End With
  End If
lbl_Exit:
  Exit Sub
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  'Intercept/repurpose Unload if user clicks form "X" close button.
  If CloseMode = 0 Then
    Cancel = True
    Me.Tag = "Canceled"
    Me.Hide
  End If
lbl_Exit:
  Exit Sub
End Sub

Function fcnSizeValidator(strSize As String) As Boolean
  strSize = UCase(strSize)
  Select Case True
    Case Is = Val(Left(strSize, 2)) <= 16 _
              And Val(Left(strSize, 2)) >= 2
      Select Case True
        Case Is = strSize Like "##[C-E]" Or _
          strSize Like "#.#[C-E]" Or _
          strSize Like "##.#[C-E]" Or _
          strSize Like "##[C-E][C-E]" Or _
          strSize Like "#.#[C-E][C-E]" Or _
          strSize Like "##.#[C-E][C-E]" Or _
          strSize Like "##[C-E][C-E][C-E]" Or _
          strSize Like "#.#[C-E][C-E][C-E]" Or _
          strSize Like "##.#[C-E][C-E][C-E]"
          fcnSizeValidator = True
        Case Else
          fcnSizeValidator = False
        End Select
    Case Else
      fcnSizeValidator = False
  End Select
lbl_Exit:
  Exit Function
End Function

'Public data strings
Public p_strCaptionLabel As String
Public p_strAnswerReturned As String

Sub PassData2()
Dim myFrm As UserForm2
  'Method 1 - Store the text to pass in a document variable.
  ActiveDocument.Variables("txtPassedToForm").Value = fcnCaptionText(2)
  'Method 2 - Pass data to form using a public declared variable.
  p_strCaptionLabel = fcnCaptionText(1)
  'Create/load instance of form.
  Set myFrm = New UserForm2
  With myFrm
    'Method 3 - Custom userform property w\publically declared data variables.
    myFrm.LabelCaption = fcnCaptionText(3)
    'Method 4 - Custom userform property w\privately declared data variables.
    'Pass (or Let) fcnCaptionText value to private form variable.
    .CaptionLabel = fcnCaptionText(4)
    .Show
  End With
  If Not myFrm.UserCancel Then
    'Method 1.
    MsgBox "Answer 1: " _
    & ActiveDocument.Variables("txtPassedToCall").Value, , "Text Returned"
    'Method 2.
    MsgBox "Answer 2: " _
    & p_strAnswerReturned, , "Text Returned"
    'Method 3.
    MsgBox "Answer 3: " & myFrm.UserAnswer, , "Text Returned"
    'Method 4.
    MsgBox "Answer 4: " & myFrm.Answer, , "Text Returned"
  End If
lbl_Exit:
  Exit Sub
End Sub

Function fcnCaptionText(ByRef lngCount As Long) As String
  Select Case lngCount
    Case 1: fcnCaptionText = "What is your name?"
    Case 2: fcnCaptionText = "How old are you?"
    Case 3: fcnCaptionText = "Where do you live?"
    Case 4: fcnCaptionText = "Are you growing tired of answering my questions?"
  End Select
lbl_Exit:
  Exit Function
End Function

'Public form data variables.
Public LabelCaption As String
Public UserAnswer As String
'Private form data variables.
Private m_strCaptionPassed As String
Private m_strAnswerReturned As String
Private m_Cancel As Boolean

Private Sub UserForm_Initialize()
  'This procedure is triggered when the form is loaded in memory.
  With Me
    'Method 1.
    .Label1.Caption = ActiveDocument.Variables("txtPassedToForm").Value
    'Method 2.
    .Label2.Caption = p_strCaptionLabel
  End With
lbl_Exit:
  Exit Sub
End Sub

Private Sub UserForm_Activate()
  'This procedure is triggered after the form loads and before it is shown to the user.
  With Me
    'Method 3.
    .Label3.Caption = .LabelCaption
    'Method 4.
    .Label4.Caption = .CaptionLabel
  End With
lbl_Exit:
  Exit Sub
End Sub

Private Sub cmdOK_Click()
  With Me
    'Method 1.
    If Len(.TextBox1.Text) > 0 Then
      ActiveDocument.Variables("txtPassedToCall").Value = .TextBox1.Text
    Else
      ActiveDocument.Variables("txtPassedToCall").Value = " "
    End If
    'Method 2.
    p_strAnswerReturned = .TextBox2.Text
    'Method 3.
    UserAnswer = .TextBox3.Text
    'Method 4.
    m_strAnswerReturned = .TextBox4.Text
    .Hide
  End With
lbl_Exit:
  Exit Sub
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  'Intercept/repurpose Unload if user clicks form "X" close button.
  If CloseMode = 0 Then
    Cancel = True
    m_Cancel = True
    Me.Hide
  End If
End Sub

Public Property Let CaptionLabel(ByVal strDataLet As String)
  m_strCaptionPassed = strDataLet
lbl_Exit:
  Exit Property
End Property

Public Property Get CaptionLabel() As String
  CaptionLabel = m_strCaptionPassed
lbl_Exit:
  Exit Property
End Property

Public Property Get Answer() As String
  Answer = m_strAnswerReturned
lbl_Exit:
  Exit Property
End Property

Public Property Get UserCancel() As Boolean
  UserCancel = m_Cancel
lbl_Exit:
  Exit Property
End Property