The Anchorage

Personal website of Gregory K. Maxey, Commander USN (Retired)

• Quarterdeck
• What's New
• Microsoft Word Tips
• Consulting
• Chain Locker
• Lucky Bag
• Contact
• Search

Do you have ad-blocking software enabled? While I respect your right to do so, your donations and the minimal advertisements on this site help to defray internet and other costs of providing this content. Please consider excluding this website from blocking or turning off the blocker while browsing this site.

This Microsoft Word Help & Microsoft Word Tips page will show you several methods to repurpose controls in the Word User Interface (UI).

What controls? What is repurposing? Both fair questions

• Controls are the building blocks of the UI. This includes the ribbon in Word 2007/2010 and the menus and toolbars in previous versions. Some controls are simply containers that group and organize other controls. Regardless of how they appear in the U/I e.g., tabs, groups, menus, toolbars, buttons, dropdowns, toggle buttons, etc., they are all controls.
• Repurposing a control is a processes temporarily or permanently changing its default function. You can repurpose a control to do something in addition to its basic function or something entirely different.

Basic Demonstration

You can create your own simple example as follows:

• Open a new document and save it.  Name it whatever.  It doesn't matter.
• Copy and paste the following VBA procedure in the "ThisDocument" module of the documents VB project:

Sub FileSave()
  If ActiveDocument.Saved Then
    MsgBox "I've already been saved so you are wasting your time."
  Else
   ActiveDocument.Save
  End If
lbl_Exit:
  Exit Sub
End Sub

See: Installing Macros for instructions on how to set up and use the macros provided in this Microsoft Word Help & Microsoft Word Tips page.

• Go back to the document click on the "Save" control.  
• Now click it again.
• Now press CTRL+s.
• Get the picture?  Let's stop wasting your time and move on shall we?

In the preceding example we repurposed the control by intercepting the Word command FileSave with VBA. This is a particularly handy method that works with a lot of Word controls. For a more detailed discussion of this method see the Microsoft Word MVP FAQ: Intercepting Events like Save and Print

Advanced Demonstration

Ok, so why would anyone want or need to repurpose a control? Let's take Mr. Spacely of intergalactic Spacely Sprockets. Like many of us, he is concerned about the environment. In order to save paper he has told George and his other employees to use "green" margins of one inch or less in all Spacely Sprockets company documents. He wants his IT gurus to devise a compliance measure.

For this example we will create a Word Template Add-In that will be loaded on all Spacely Sprockets computers. We will repurpose the necessary controls by monitoring control click events.

• Open a new document, save it as a template in your Word Startup directory.
• Open the VB Editor, insert a standard project module and paste the following VBA code into the project.

Private WithEvents ctrlEvent As CommandBarButton

Sub AutoExec()
  Set ctrlEvent = Application.CommandBars("Menu Bar").Controls("File").Controls("Print...")
lbl_Exit:
  Exit Sub:
End Sub

Private Sub ctrlEvent_Click(ByVal Ctrl As CommandBarButton, CancelDefault As Boolean)
  CancelDefault = True
  Select Case True
    Case ActiveDocument.PageSetup.RightMargin > 72
      MsgBox "Set green document margins and try again."
    Case ActiveDocument.PageSetup.LeftMargin > 72
      MsgBox "Set green document margins and try again."
    Case Else
      CancelDefault = False
  End Select
lbl_Exit:
  Exit Sub
End Sub

• Save the VB project and close the VB Editor.
• Save and close the template.
• Shutdown and restart Word.

In the preceding example we repurposed the Print... control by monitoring the click event.

• When the event is detected, we suspend the default function of the control and check if the document margins comply with Mr. Spacely's green policies.
• Users are notified when a non-compliant document is detected and it is not printed.
• In the case of a fully compliant document we resume the default function of the control and print the document.

Notes:
     1.  Unlike intercepting commands demonstrated in the first example, click event only monitors a control click.  It does not monitor other execution methods e.g., keyboard shortcuts.

     2. For more on template add-ins and how to load them, see: Organizing Your Macros/Template Add-ins at: Installing Macros

For the final example, we will repurpose the FilePrint and FilePrintQuick controls on the Word 2007 Office Menu.

• If not already installed, download and install the Office Custom UI Editor application. See my: Customize the Ribbon for a link where you can review and download this application for no charge.
• Open Word and open a new file. Save the file as a macro enabled template in your Word Startup directory. I saved my template as "RepurposePrintControls.dotm"
• Open the VB Editor and insert a standard project module. Rename the module "RibbonControls" and paste in the following VBA code:

Private Sub RepurposedPrint(ByVal control As IRibbonControl, ByRef cancelDefault)
  cancelDefault = True
  Select Case True
    Case ActiveDocument.PageSetup.RightMargin > 72
      MsgBox "Set green document margins and try again."
    Case ActiveDocument.PageSetup.LeftMargin > 72
      MsgBox "Set green document margins and try again."
    Case Else
      cancelDefault = False
  End Select
lbl_Exit:
  Exit Sub
End Sub

• Save the VB project and close the VB Editor.
• Close the template and close Word.
• Open the Office Custom UI Editor application and open the template in the editor.
• Paste the following RibbonXML script in the editor Custom UI code window:

<customUI xmlns="http://schemas.microsoft.com/office/2006/01/customui">
 <commands>
  <command idMso="FilePrint" onAction="RibbonControl.RepurposedPrint"/>
  <command idMso="FilePrintQuick" onAction="RibbonControl.RepurposedPrint"/>
  </commands>
</customUI>

• Save the customization, close the template and close the editor.
• Open Word and verify only "green" documents will print!!

Note: Unlike intercepting the click event, repurposed ribbon controls capture both the click event and keyboard shortcuts!

That's it! I hope you have found this tips page useful and informative.  You can download the template add-in which includes the RibbonXML and VBA demonstrated above here: Repurpose Print Controls.

This page was last updated on March 09, 2021

Website Privacy Statement

Back to top    Back to Word Tips